root/plagger/trunk/my-plugins/Subscription-Toranoana/Toranoana.pm

package Plagger::Plugin::Subscription::Toranoana;

use strict;
use warnings;

use base qw( Plagger::Plugin );

use Plagger::Util;
use Plagger::Feed;
use Plagger::Entry;
use Plagger::UserAgent;

use URI;
use HTML::TreeBuilder::XPath;

sub register {
    my ($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => \&load,
    );
}

sub load {
    my($self, $context) = @_;

    my $feed = Plagger::Feed->new;
       $feed->aggregator( sub { $self->aggregate(@_); });
    $context->subscription->add($feed);
}

sub aggregate {
    my($self, $context) = @_;

    my @tora_newka_shops = @{$self->conf->{shop}};
    my $day = $self->conf->{day} || _today(time);

    for my $shop (@tora_newka_shops) {
        $self->aggregate_feed($context, $shop, $day);
    }
}


sub aggregate_feed {
    my($self, $context, $shop, $day) = @_;
    
    my $newka_uri = URI->new("http://www.toranoana.jp/shop/newka/${day}/${shop}_all.html");
    my $response = Plagger::UserAgent->new->fetch($newka_uri);
    if ($response->is_error) {
        Plagger->context->log(error => "GET $newka_uri failed: " .
                              $response->http_status . " " .
                              $response->http_response->message);
    }
    my $data = Plagger::Util::decode_content($response->content);
    
    my $tree = HTML::TreeBuilder::XPath->new;
    
    $tree->parse($data);
    my $path = '//body/div[3]/table';
    
    my $booknodes;
    eval {
        $booknodes = $tree->findnodes($path);
    } or die $@;
    
    my $feed = Plagger::Feed->new;
    $feed->title("Toranoana\@$shop");
    $feed->link($newka_uri);
    for my $book (@$booknodes) {
        $self->_add_entry($context, $feed, $book);
    }
    $context->update->add($feed);
}

sub _add_entry {
    my($self, $context, $feed, $book) = @_;
    
    my $html = $book->as_HTML('<>&');
    if (my @table = ($html =~ m|<td[^>]*>([^<]*)</td>|g)) {
        my $book_id = $table[0];
        
        if (
            ($html =~ /color\: \#FF99FF/)
            and ($self->conf->{yaoi_block})
            )
        {
            $context->log(info => "$book_id is yaoi");
            return;
        }
        
        $book_id =~ /^(\d{2})(\d{4})(\d{2})(\d{2})/;
        my $book_link = "http://www.toranoana.jp/mailorder/article/$1/$2/$3/$4/$book_id.html";
        my $img_link  = "http://img.toranoana.jp/img/$1/$2/$3/$4/$book_id-%d.gif";
        my $body;
        my $tag = sprintf("<img src=\"%s\" />", $img_link);
        for my $i (1..3) {
            $body .= sprintf($tag, $i) . "\n";
        }
        
        my $entry = Plagger::Entry->new;
        $entry->title($table[2]);
        $entry->link($book_link);
        $entry->body($body);
        $entry->author($table[1]);
        $entry->tags([$table[3]]);
        
        $feed->add_entry($entry);
    }
}

sub _today {
    my @t = localtime(shift);
    my $day = sprintf("%02d%02d", $t[4]+1, $t[3]);
    return $day;
}

1;