root/plagger/trunk/my-plugins/Subscription-BrowserHistory/BrowserHistory.pm

package Plagger::Plugin::Subscription::BrowserHistory;
use strict;
use base qw( Plagger::Plugin );

sub init {
    my $self = shift;
    $self->SUPER::init(@_);

    my $browser =$self->conf->{browser} || $self->auto_configure;
    my $class = __PACKAGE__ . "::$browser";
    $class->require or Plagger->context->error("Error loading $class: $@");

    bless $self, $class;
}

sub auto_configure {
    my $self = shift;

    my $path = $self->conf->{path};
    if ($path) {
        # TODO: Now this only supports Mozilla histories.
        if ($path =~ /history\.dat$/) {
            Plagger->context->log(debug => "$path is a Mozilla history");
            return 'Mozilla';
        }
    }
}

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => $self->can('load'),
    );
}

sub load { die 'Override load' }

1;
__END__

=head1 NAME

Plagger::Plugin::Subscription::BrowserHistory - Subscription to URLs in Browser History

=head1 SYNOPSIS

  - module: Subscription::BrowserHistory
    config:
      browser: Mozilla
      path: /path/to/history.dat

=head1 DESCRIPTION

This plugin allows you to subscribe to your browser history.

=head1 CONFIG

=over 4

=item browser

Specify your broser name. 

=item path

Specify path to your browser history file.

=back

=head1 AUTHOR

Yohei Fushii

=head1 SEE ALSO

L<Plagger>, L<File::Mork>

=cut