root/plagger/trunk/my-plugins/Filter-FetchEnclosure-Mplayer/Mplayer.pm

package Plagger::Plugin::Filter::FetchEnclosure::Mplayer;
use strict;
use base qw(Plagger::Plugin::Filter::FetchEnclosure);
use File::Path;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'update.entry.fixup' => \&fetch,
    );
}

sub init {
    my $self = shift;
    $self->SUPER::init(@_);

    $self->{ua} = Plagger::UserAgent->new;
}

sub fetch {
    my($self, $context, $args) = @_;

    unless (defined $self->conf->{type}) {
        $context->log(error => q{config 'type' is not set.});
    }
    my $file_name_base = $args->{entry}->date->strftime('%Y%m%d-%H%M');

    for my $enclosure ($args->{entry}->enclosures) {

        unless ($enclosure->type =~ $self->conf->{type}) {
            $enclosure->local_path('dummy') unless $enclosure->local_path;
            next;
        }
        
        my $dir_name = $self->conf->{sub_dir_name} || $args->{feed}->id_safe;
        my $feed_dir
            = File::Spec->catfile($self->conf->{dir}, $dir_name);
        unless (-e $feed_dir && -d _) {
            $context->log(info => "mkdir $feed_dir");
            mkdir $feed_dir, 0777;
        }

        my $stream_url     = ($self->_get_stream_urls_for($enclosure))[0];
        my $enclosure_num  = 0;
        my $file_name      = "$file_name_base-$enclosure_num";
        my $file_path_base = File::Spec->catfile($feed_dir, "$file_name");
        my $output_path    = "$file_path_base.wav"; 

        # Check existence of fetched data
        my $fetched_extension = $self->conf->{consider_fetched} || 'mp3';
        my $fetched_data_path = "$file_path_base.$fetched_extension";
        if (-e $fetched_data_path || -e $output_path) {
            my $length = -s _;
            $ enclosure->url($enclosure->url);
            $enclosure->length($length);
            $enclosure->type('audio/x-wav');
            $enclosure->local_path($output_path);
            $context->log(debug => $enclosure->url . "is already stored in $output_path");
            next;
        }

        $context->log(info => "fetch $stream_url to $output_path");

        my @options = split(/ /,$self->conf->{option}) or ();
        my @command = (
            'mplayer',
            $stream_url, 
            '-vc', 'dummy', 
            '-vo', 'null', 
            '-ao', "pcm:file=$output_path", 
            '-quiet', 
            @options,
        );

        system (@command);

        if (!$? && -s $output_path ) {
            my $length = -s _;
            $enclosure->url($stream_url);
            $enclosure->length($length);
            $enclosure->type('audio/x-wav');
            $enclosure->local_path($output_path);

            $context->log(info => "Dumping to $output_path is done.");
        }
        else {
            $context->log(warn => "Can not dump to $output_path");
            $context->log(info => "Deleting $output_path");
            unlink $output_path or $context->log(warn => "Can not delete $output_path.");
        }
    }
}

sub _get_stream_urls_for {
    my ($self, $enclosure) = @_;

    my @stream_urls;
    
    # TODO support multi stream addresses
    if ($enclosure->type =~ /asf/) {
        my $res = $self->{ua}->fetch($enclosure->url)
            or Plagger->context->log;
        @stream_urls 
            = $res->content =~ m!((?:http|mms)://.*?\.(?:wmv|wsx|wma|asf))!g;
    }
    elsif ($enclosure->type =~ /realaudio/) {
        my $res = $self->{ua}->fetch($enclosure->url)
            or Plagger->context->log;
        @stream_urls
            = $res->content =~ m!(rtsp://.*?\.(?:rm|smi))!g;
    }

    Plagger->context->log(warn => "Cannot get stream url for " .  $enclosure->url)
        unless @stream_urls;

    return @stream_urls;
}

1;

__END__

=head1 NAME

Plagger::Plugin::Filter::FetchEnclosure::Mplayer - Fetch enclosures using mplayer

=head1 SYNOPSIS

  - module: Filter::FetchEnclosure::Mplayer
    config:
      dir: /path/to/download
      sub_dir_name: sub_directory_name
      type: asf

=head1 DESCRIPTION

This plugin dumps audio/video stream to a wav file.

=head1 AUTHOR

Yohei Fushii

=head1 SEE ALSO

L<Plagger>

=cut