root/plagger/trunk/my-plugins/CustomFeed-SOS/SOS.pm

package Plagger::Plugin::CustomFeed::SOS;
use strict;
use base qw( Plagger::Plugin );

use Encode;
use Plagger::UserAgent;
use Plagger::Util qw( decode_content );

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'customfeed.handle' => \&handle,
    );
}

sub handle {
    my($self, $context, $args) = @_;

    # for sos-dan radio sibu only
    if ($args->{feed}->url =~ m!^http://lantis-net.com/haruhi/!) {
        $self->aggregate($context, $args);
        return 1;
    }

    return;
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $url = $args->{feed}->url;
    $context->log(info => "GET $url");

    my $agent = Plagger::UserAgent->new;
    my $res = $agent->fetch($url, $self);

    if ($res->is_error) {
        $context->log(error => "GET $url failed: " . $res->status_code);
        return;
    }

    my $content = decode_content($res);

    my $feed = Plagger::Feed->new;
    $feed->title(decode_content("ＳＯＳ団ラジオ支部"));
    $feed->link($url);

    my $re = <<'RE';
<!--00[1-5]-->.*?<span class="syokai2">\s*\[\s*(.*?)\s*\]\s*(.*?)\s*<span class="date">\s*(\d{4}年\s*\d+\s*月\s*\d+\s*日)\s*放送分\s*</span>\s*</span>.*?<div class="w95 ma mb10">(.*?)</div>.*?<a href="(\d+.asx)".*?>.*?</a>.*?<!--00[1-5]-->
RE
    $re = decode_content($re);

    $content =~ s/\r\n/\n/g;

    my @matches;
    my @keys = qw( title date body enclosure );
    my $date_format = decode_content("%Y年%m月%d日");
    $url =~ m!(.*/)!;
    my $base = $1;

    while ($content =~ /$re/gs) {
        my $data;
        @{$data}{@keys} = ($1.$2, $3, $4, $5);
        $data->{date} = Plagger::Date->strptime($date_format, $data->{date});

        my $entry = Plagger::Entry->new;
        $entry->title($data->{title});
        $entry->date($data->{date});
        $entry->body($data->{body});

        my $res = $agent->fetch(URI->new_abs($data->{enclosure}, $base), $self);
        if ($res->is_error) {
            $context->log(error => "GET $url failed: " . $res->status_code);
            return;
        }

        my $meta = decode_content($res);

        while ($meta =~ m!http://.*?\.wsx!g) {
            $self->log(info => "Adding enclosure $&");
            my $enclosure = Plagger::Enclosure->new;
            $enclosure->url($&);
            $enclosure->auto_set_type;
            $entry->add_enclosure($enclosure);
        }

        $feed->add_entry($entry);
    }

    $context->update->add($feed);
}

1;

__END__

=head1 NAME

Plagger::Plugin::CustomFeed::SOS - Custom feed for SOS-dan radio shibu

=head1 SYNOPSIS

  - module: Subscription::Config
    config:
      feed:
        - http://lantis-net.com/haruhi/radio.html

  - module: CustomFeed::SOS

=head1 DESCRIPTION

This plugin creates a custom feed off of net radio - SOS-dan radio shibu

=head1 AUTHOR

Yohei Fushii

=head1 SEE ALSO

L<Plagger>, L<http://lantis-net.com/haruhi/>

=cut