root/plagger/trunk/my-plugins/CustomFeed-MangaOhClub/MangaOhClub.pm

package Plagger::Plugin::CustomFeed::MangaOhClub;
use strict;
use base qw( Plagger::Plugin );

use Encode;
use String::Format;
use Plagger::UserAgent;
use Plagger::Util qw( decode_content );
use Plagger::Date;

our $CATEGORY = {
    comic =>  {
        title   => 'コミック',
        csv_re  => qr{^"([^"]*)","(\d+/\d+/\d+)","([^"]*)","([^"]*)","([^"]*)","([^"]*)"$},
        capture => ['publisher', 'date', 'title', 'author', 'cost', 'info'],
        template => << "TEMPLATE",
<dl>
<dt>作者</dt>
<dd>%a</dd>
<dt>出版社</dt>
<dd>%p</dd>
<dt>発売日</dt>
<dd>%d</dd>
<dt>価格</dt>
<dd>%c円</dd>
</dl>
TEMPLATE
    },
    av    => {
        title    => '音楽&映像',
        csv_re   => qr{^"([^"]*)","(\d+/\d+/\d+)","([^"]*)","([^"]*)","[^"]*","([^"]*)","([^"]*)"$},
        capture  => ['kind', 'date', 'title', 'publisher', 'cost', 'info'],
        template => << "TEMPLATE",
<dl>
<dt>メーカー</dt>
<dd>%p</dd>
<dt>発売日</dt>
<dd>%d</dt>
<dt>種別</dt>
<dd>%k</dd>
<dt>価格</dt>
<dd>%c円</dd>
<dt>補足</dt>
<dd>%i</dd>
</dl>
TEMPLATE
    },
    bunko => {
        title   => '文庫&漫画文庫',
        csv_re  => qr{^"([^"]*)","([^"]*)","([^"]*)","(\d+/\d+/\d+)","([^"]*)","([^"]*)","([^"]*)","([^"]*)","([^"]*)"$},
        capture => ['type', 'publisher', 'bunko',  'date', 'title', 'author', 'eshi', 'cost', 'info'],
        template => << "TEMPLATE",
<dl>
<dt>作者</dt>
<dd>%a %e</dd>
<dt>出版社</dt>
<dd>%p - %b</dd>
<dt>発売日</dt>
<dd>%d</dd>
<dt>価格</dt>
<dd>%c円</dd>
<dt>補足</dt>
<dd>%i</dd>
</dl>
TEMPLATE
    },
    june =>  {
        title   => '耽美コミック･ノベル',
        csv_re  => qr{^"([^"]*)","([^"]*)","(\d+/\d+/\d+)","([^"]*)","([^"]*)","([^"]*)","([^"]*)"$},
        capture => ['publisher', 'type', 'date', 'title', 'author', 'eshi', 'cost'],
        template => << "TEMPLATE",
<dl>
<dt>作者</dt>
<dd>%a %e</dd>
<dt>出版社</dt>
<dd>%p %t</dd>
<dt>発売日</dt>
<dd>%d</dd>
<dt>価格</dt>
<dd>%c円</dd>
</dl>
TEMPLATE
    },
};

sub register {
    my ($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => \&load,
    );
}

sub load {
    my($self, $context) = @_;

    my $feed = Plagger::Feed->new;
       $feed->aggregator( sub { $self->aggregate(@_); });
    $context->subscription->add($feed);
}

sub aggregate {
    my($self, $context, $args) = @_;
    for my $type (@{$self->conf->{category} || ['comic']}) {
        $context->error("$type not found") unless $CATEGORY->{$type};
        $self->aggregate_feed($context, $type, $args);
    }
}

sub aggregate_feed {
    my($self, $context, $type, $args) = @_;

    my($day, $month, $year) = (localtime)[3, 4, 5];
    $year  += 1900;
    $month += 1;

    my $uri = sprintf("http://www.mangaoh.co.jp/download/$type%d%02d.csv", $year, $month);
    $context->log(info => "GET $uri");

    my $agent = Plagger::UserAgent->new;
    my $res = $agent->fetch($uri, $self);
    if ($res->http_response->is_error) {
        $context->log(error => "GET $uri failed: " . $res->http_response()->status_line);
        return;
    }
    my $content = decode_content($res);

    my $feed = Plagger::Feed->new;
    $feed->title(decode_utf8("まんが王倶楽部 $CATEGORY->{$type}->{title}"));
    $feed->link($uri);

    my $future_for = $self->conf->{future_for} || 0;

    my @lines = split /\r\n/, $content;
    my $minute = 0;
    for my $line (@lines) {
        my $data = $self->hash_from_line($type, $line);
        next unless $data;
        
        my $date = Plagger::Date->strptime('%y/%m/%d', $data->{date});
           $date->set_time_zone($context->conf->{timezone});
        next if $date->day > $day + $future_for;
            
        my $body = stringf (decode_utf8($CATEGORY->{$type}->{template}), $data);
        my $entry = Plagger::Entry->new;

        $entry->title($data->{title});
        $entry->author($data->{author});
        $entry->date($date);
        $entry->body($body);
        $entry->link("$uri?" . $entry->digest);
        $entry->id($entry->digest);
        push @{$entry->tags}, $data->{info};

        $feed->add_entry($entry);
        $context->log(debug => "$date $data->{title}");
    }

    $context->update->add($feed);

    return 1;
}

sub hash_from_line {
    my($self, $type, $line) = @_;

    my @match = $line =~ $CATEGORY->{$type}->{csv_re};
    return unless @match;

    my $data;
    @{$data}{@{$CATEGORY->{$type}->{capture}}} = @match;
    for my $key (keys %$data) {
        $data->{substr($key, 0, 1)} = $data->{$key};
    }

    return $data;
}

1;