root/plagger/trunk/my-plugins/CustomFeed-JoyHack/JoyHack.pm

package Plagger::Plugin::CustomFeed::JoyHack;
use strict;
use base qw( Plagger::Plugin );

use Encode;
use Plagger::UserAgent;
use Plagger::Util qw( decode_content extract_title );
use Plagger::Date;


sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'customfeed.handle' => \&handle,
    );
}

sub handle {
    my($self, $context, $args) = @_;

    return $self->aggregate($context, $args);
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $url = $args->{feed}->url;
    $context->log(info => "GET $url");

    my $agent = Plagger::UserAgent->new;
    my $res = $agent->fetch($url, $self);

    if ($res->http_response->is_error) {
        $context->log(error => "GET $url failed: " . $res->status_line);
        return;
    }

    my $content = decode_content($res);

    my $feed = Plagger::Feed->new;
    $feed->title('JoyHack');
    $feed->link($url);
    my $host = $self->conf->{host} || 'localhost';


    my @lines = split /\n/, $content;
    for my $line (@lines) {
        my ($title, $singer, $works, $author, $date ,$id) = 
            $line =~ /([^\t]*)\t([^\t]*)\t([^\t]*)\t([^\t]*)\t([^\t]*)\t([^\t]*)/;

        my $link = "http://$host/cgi-bin/hack.cgi?m=1&p=$id";
        my $summary = join ' ', ($singer, $works);

        my $entry = Plagger::Entry->new;
        $entry->title($title);
        $entry->link($link);
        $entry->author($author);
        $entry->date(Plagger::Date->strptime('%y/%m/%d', $date));
        $entry->id($id);
        $entry->body($summary);
        push @{$entry->tags}, $_ for ($singer, $works, $author);

        $feed->add_entry($entry);
        $context->log(debug => "$date $title ($link)");
    }

    $context->update->add($feed);

    return 1;
}

1;