root/plagger/trunk/my-plugins/CustomFeed-FileList/FileList.pm

package Plagger::Plugin::CustomFeed::FileList;
use strict;
use base qw( Plagger::Plugin );

use Encode;
use Plagger::UserAgent;
use Plagger::Date;
use Digest::MD5 qw(md5_hex);


sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'customfeed.handle' => \&handle,
    );
}

sub handle {
    my($self, $context, $args) = @_;

    return $self->aggregate($context, $args);
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $url = $args->{feed}->url;
    $context->log(info => "GET $url");

    my $agent = Plagger::UserAgent->new;
    my $res = $agent->fetch($url, $self);

    if ($res->http_response->is_error) {
        $context->log(error => "GET $url failed: " . $res->status_line);
        return;
    }

    my $content = decode_utf8($res->content);

    my $feed = Plagger::Feed->new;
    $feed->title('filelist') unless $feed->title;
    $feed->link($url);


    # input resutl of 'ls -laRT'
    my @files = split /\n/, $content;
       @files = map  {s!/$!!; $_}
                grep {! m!\.?\./$!}
                grep {m!^[-d][-rwx]+!} @files;
    for my $file (@files) {
        my @infos = split /\s+/, $file; 
        next if ($self->conf->{dir_only} && $infos[0] !~ m!^d!);

        my $title  = $infos[9];
        next if ($title =~ /^\.\.?$/); 
        my $author = $infos[2];
        my $date   = join ' ', $infos[5], $infos[6], $infos[7], $infos[8];

        $context->log(debug => $date);

        my $entry = Plagger::Entry->new;
        $entry->title($title);

        $entry->author($author);
        $entry->date(Plagger::Date->strptime('%m %d %T %Y', $date));
        $entry->id(md5_hex(encode_utf8($file)));

        $feed->add_entry($entry);
    }

    $context->update->add($feed);

    return 1;
}

1;