root/plagger/trunk/my-plugins/CustomFeed-FTP/FTP.pm

package Plagger::Plugin::CustomFeed::FTP;
use strict;
use base qw( Plagger::Plugin );

use Plagger::Date;
use Net::FTP;

sub register {
    my($self, $context) = @_;
    $context->register_hook(
        $self,
        'subscription.load' => \&load,
    );  
}   

sub load {
    my($self, $context) = @_;
    
    my $feed = Plagger::Feed->new;
       $feed->aggregator(sub { $self->aggregate(@_) });
    $context->subscription->add($feed);
}

sub aggregate {
    my($self, $context, $args) = @_;

    my $host = $self->conf->{host};
    my $ftp = Net::FTP->new($host, Timeout => 300);

    unless ($ftp->login($self->conf->{username}, $self->conf->{password})) {
        $context->log(error => "Login to $host failed.");
        return;
    }

    my $root = $self->conf->{root} || '.';
    my $file_infos = [];

    $ftp->cwd($root);
    $self->load_file_info($context, $file_infos, $ftp, '');
    
    $ftp->quit;

    my $base_uri = "ftp://" . $self->conf->{username} . '@' ."$host/$root";

    my $feed = Plagger::Feed->new;
    $feed->title("$host/$root");
    $feed->link($base_uri);

    for my $file_info (@$file_infos) {
        next if ($self->conf->{dir_only} && !$file_info->{is_dir});

        my $entry = Plagger::Entry->new;

        $entry->title($file_info->{name});
        $entry->id($file_info->{path});
        $entry->link($base_uri . $file_info->{path});
        $entry->date( Plagger::Date->from_epoch($file_info->{mdtm}));
        $entry->body($file_info->{path});

        $feed->add_entry($entry);
    }

    $context->update->add($feed);
}

sub load_file_info {
    my($self, $context, $list, $ftp, $dir) = @_;

    $context->log(debug => "Listing files under $dir");
    my @files = $ftp->ls();
    unless (@files) {
        $context->log(error => "Can't list $dir .");
        return 0;
    }

    my $dir_mdtm = 0;
    for my $file (@files) {
        $context->log(debug => "Processing $file.");
        next if ($self->conf->{skip_hidden} && $file =~ /^\./);
        my $file_info = {
            name   => $file,
            path   => File::Spec->catfile($dir, $file),
            mdtm   => 0,
            id_dir => 0,
        };
        if ($ftp->cwd($file)) {
            $file_info->{is_dir} = 1;
            $file_info->{path}  .= '/';
            my $next_dir = File::Spec->catdir($dir, $file);
            $file_info->{mdtm} = $self->load_file_info($context, $list, $ftp, $next_dir);
            $ftp->cdup();
        } else {
            $file_info->{mdtm} = $ftp->mdtm($file) || 0;
            $dir_mdtm = $file_info->{mdtm} if $file_info->{mdtm} > $dir_mdtm;
        }

        push @$list, $file_info;
    }
    return $dir_mdtm;
}

1;